macro make_figure plot_ratio=1 show_kolb=0 show_arrows=1
*
* NOTE! this macro is designed to be run from a SUBdirectory
*
* plot_ratio=0 means the right-hand panels will plot R^2_{\mu,2}
* plot_ratio=1 means the right-hand panels will plot R^2_{\mu,2}/R^2_{\nu,0}
*            where \nu="side" for \mu="out-side" and \nu=\mu otherwise
*
vec/crea pass(6) r
exec ./specifics#set_param1
calcmax = $SIGMA(pass(1))
ptmax = $SIGMA(pass(2))
*
op ndat
op utit
set lwid 8
set fwid 8
set hwid 8
set csiz 0.45
set vsiz 0.5
set xval 0.45
set xwin 0.001
set ywin 0.001
set bcol 1
set ylab 0.9
set xlab 1.6
set gsiz 0.6
set chhe 0.6   | sets the character size for the new y-axis labels
set txal 20    | center justified
*
* set left and right page margins.  Otherwise, the labels get cut off...
set xmgl 2.5   | is default 2.5
set xmgr 3.0  | is default 2.0


*
size 20 30
zone 2 4
*
if ([plot_ratio].eq.1) then
*  title '  n=0                              (n=2)/(n=0)'
   title ''
else
  title '  n=0                              n=2'
endif
vec/crea par(2) r
do izone=1,8
  case [izone] in
  (1) | nominally R^2_{os,0} -- use it for key
      if ([plot_ratio].eq.0) then
         lab = 'R^2?OS,n! (fm^2!)'
      endif
  (2) var = R2os2
      var2 = R2s0
      if ([plot_ratio].eq.1) then
         lab = 'R^2?OS,2!/R^2?S,0!'
      endif
  (3) var = R2o0
      if ([plot_ratio].eq.1) then
         lab = 'R^2?O,0! (fm^2!)'
      else
         lab = 'R^2?O,n! (fm^2!)'
      endif
  (4) var = R2o2
****      var2 = R2o0
      var2 = R2s0
      if ([plot_ratio].eq.1) then
         lab = 'R^2?O,2!/R^2?S,0!'
      endif
  (5) var = R2s0
      if ([plot_ratio].eq.1) then
         lab = 'R^2?S,0! (fm^2!)'
      else
         lab = 'R^2?S,n! (fm^2!)'
      endif
  (6) var = R2s2
      var2 = R2s0
      if ([plot_ratio].eq.1) then
         lab = 'R^2?S,2!/R^2?S,0!'
      endif
  (7) var = R2l0
      if ([plot_ratio].eq.1) then
         lab = 'R^2?l,0! (fm^2!)'
      else
         lab = 'R^2?l,n! (fm^2!)'
      endif
  (8) var = R2l2
      var2 = R2l0
      if ([plot_ratio].eq.1) then
         lab = 'R^2?l,2!/R^2?l,0!'
      endif
  endcase
  exec ./specifics#set_histo_limits [izone] [plot_ratio] [show_kolb]
  ymin = $SIGMA(pass(1))
  ymax = $SIGMA(pass(2))
*
* here, we just REset the limits on the ratio plots, to a standard number
*
*  if ([plot_ratio].eq.1) then
*     case [izone] in
*     (2)
*        ymin = -0.09
*        ymax = 0.29
*     (4)
*        ymin = -0.29
*        ymax = 0.09
*     (6)
*        ymin = -0.09
*        ymax = 0.29
*     (8)
*        ymin = -0.02
*        ymax = 0.009
*     endcase
*  endif
**
**
  if ([izone].eq.1) then
    zone 2 4
    hplo/null 0 10 0 10 a
  else
    zone 2 4 [izone] s
    if ([izone].eq.7) then
      ptmaxplot = [ptmax]-0.0001
    else
      ptmaxplot = [ptmax]
    endif
    2dhisto 100 ' ' 40 0 [ptmaxplot] 40 [ymin] [ymax]
  endif
  if ([izone].lt.7) then
    set yval 200
  else
      set yval 0.2
  endif
  if (([izone].eq.1).or.([izone].eq.3).or.([izone].eq.5).or.([izone].eq.7)) then
    set xval 0.1
    set ndvy 10510.00
  else
    set xval -7.6
    set ndvy 10510.01
  endif
  if ([izone].ne.1) then
    hi/plo 100
    graph/hplo/tick
  endif

* x-axis labels....
  if ([izone].ge.7) then
      set asiz 0.5
      atit 'p?T! (GeV/c)'
  endif
* y-axis labels....
  if (([izone].eq.3).or.([izone].eq.5).or.([izone].eq.7)) then
*    set asiz 0.65
*    atit ' ' [lab]
     set TANG 90          | 90-degree rotation
     xlab = [ptmax]*(-0.2)
     ylab = [ymax]+[ymin]
     ylab = 0.5*[ylab]
     itx [xlab] [ylab] [lab]
  endif
  if ([plot_ratio].eq.0) then
    if ([izone].eq.1) then
*      set asiz 0.65
*      atit ' ' [lab]
     set TANG 90          | 90-degree rotation
     itx -2 5 [lab]
    endif
  else
    if (([izone].eq.2).or.([izone].eq.4).or.([izone].eq.6).or.([izone].eq.8)) then
*      set xlab 1.76
*      set asiz 0.65
*      atit ' ' [lab] ! ! R
       set TANG 270          | negative 90-degree rotation
       xlab = [ptmax]*(0.3)
       xlab = [xlab]+[ptmax]
       ylab = [ymax]+[ymin]
       ylab = 0.5*[ylab]
       itx [xlab] [ylab] [lab]
    endif
  endif
*
  do icalc=1,[calcmax]
    set basl 0.01
    case [icalc] in
    (1) lt = 1
    (2) lt = 12
    (3) set basl 0.025
        lt = 12
    (4) lt = 13
    (5) set basl 0.005
        lt = 12
    endcase
    exec ../make_figure#read_data [icalc] | note the ".."  That's b/c it is to be run from subdirectory
    set ltyp [lt]
    igset ltyp [lt]
    if ([izone].eq.1) then
      exec ./specifics#do_caption [icalc] [lt]
    else
      if ([plot_ratio].eq.0) then
         pline $VDIM(pt) pt [var]
      else
         if (([izone].eq.3).or.([izone].eq.5).or.([izone].eq.7)) then
            pline $VDIM(pt) pt [var]
         else
            vdiv [var] [var2] rat
            pline $VDIM(pt) pt rat
            if ([show_arrows].eq.1) then
              exec ../make_figure#draw_arrow [izone] [icalc]
            endif
         endif
      endif
    endif
  enddo  | icalc
*
*
  if ([show_kolb].ne.0) then
    set ltyp 1
    do icalc=1,[show_kolb]
      case [icalc] in
      (1) igset plci 3
      (2) igset plci 6
      endcase
      exec ../make_figure#read_kolb [icalc]
      if ([izone].ne.1) then
        if ([plot_ratio].eq.0) then
          pline $VDIM(pt) pt [var]
        else
          if (([izone].eq.3).or.([izone].eq.5).or.([izone].eq.7)) then
            pline $VDIM(pt) pt [var]
          else
            vdiv [var] [var2] rat
            pline $VDIM(pt) pt rat
          endif
        endif
      endif
    enddo
    igset plci 1
  endif
*
*
enddo    | izone
*


return

macro draw_arrow izone icalc
set plci 2
set ltyp 1
igset ltyp 1
yval = $SIGMA(yarro([icalc]))
xval = -0.1
if (([izone].eq.2).or.([izone].eq.6)) then
   arrow [xval] 0 [yval] [yval]
elseif ([izone].eq.4) then
   yval = -[yval]
   arrow [xval] 0 [yval] [yval]
endif
set plci 1
return


macro read_kolb icalc
vec/del pt
case [icalc] in
(1) file='./KolbHydro/RHIC_Osc_vs_kT.vec'
(2) file='./KolbHydro/IPES_Osc_vs_kT.vec'
endcase
vec/rea pt,R2o0,R2o2,R2s0,R2s2,R2os0,R2os2,R2l0,R2l2 [file]
return


macro read_data icalc
*
vec/del pt
vec/rea pt,npi,v2pi,R2o0,R2o2,r3,R2s0,R2s2,r6,R2os0,R2os2,r9,R2l0,R2l2,r12 'Calc'//[icalc]//'/pions-vs-pT.BW' ! ! -/%/
vec/rea params 'Calc'//[icalc]//'/input.inp'
*
return
*