macro make_figure
*
* this macro designed to run from a subdirectory (two levels down) where
*  a kumac called "specifics.kumac" sits.  It contains
*  macros which tell
*  - the number of calculations
*  - WHICH calculations
*  - the maximium and minimum of the spectra hiso (or?)
*  - the angles and positions of the labels "proton" and "pion"
*
* can change the following vector in specifics.kumac if you like...
vec/crea hmm(2) r 0.001 1.2 
exec specifics#give_specs
calcmax = $SIGMA(ncalc)
hmin = $SIGMA(hmm(1))
hmax = $SIGMA(hmm(2))
*
op ndat
op utit
set lwid 8
set fwid 8
set hwid 8
set csiz 0.4
set vsiz 0.45
set xval 0.45
set xlab 1.4

exec ../../sizes_etc

*
2dhisto 100 ' ' 40 0 2.0 40 [hmin] [hmax]
op logy
hi/plo 100
atit 'p?T! (GeV/c)' 'dN/p?T!dp?T! (arb. units)'
*
do jjcalc=1,[calcmax]
  icalc = $SIGMA(calcs([jjcalc]))

  set basl 0.01
  case [jjcalc] in
  (1) lt = 1
  (2) lt = 12
  (3) set basl 0.025
      lt = 12
  (4) lt = 13
  endcase
* also try lt=15??
  exec ../../make_figure#read_and_normalize_data [icalc]
  set ltyp [lt]
  igset ltyp [lt]
  SIGMA np = log10(np)     | gotta do this because
  SIGMA npi = log10(npi)   | stupid pline doesn't work with logs!
  pline $VDIM(pt) pt np
  pline $VDIM(pt) pt npi
*
  exec specifics#make_key [icalc] [lt]
enddo
*
set txfp -20
set chhe 0.5
set tang $SIGMA(alab(1))
itx $SIGMA(xlab(1)) $SIGMA(ylab(1)) 'pions'
set tang $SIGMA(alab(2))
itx $SIGMA(xlab(2)) $SIGMA(ylab(2)) 'protons'


return


macro read_and_normalize_data icalc
*
vec/rea pt,npi,v2pi,r1,r2,r3,r4,r5,r6,r7,r8,r9,r10,r11,r12 '../../../DataFiles/Calc'//[icalc]//'/pions-vs-pT.BW' ! ! -/%/
vec/rea pt,np,v2p,r1,r2,r3,r4,r5,r6,r7,r8,r9,r10,r11,r12 '../../../DataFiles/Calc'//[icalc]//'/protons-vs-pT.BW' ! ! -/%/
*
* normalize to first point (the one at pT=0)
*
vscale npi $SIGMA(1.0/npi(1)) npi
vscale np $SIGMA(1.0/np(1)) np
*
return
*